group = "com.infendro"
version = "1.0.0"

repositories {
    maven("https://git.infendro.com/api/packages/Infendro/maven")
    mavenCentral()
}

plugins {
    alias(libs.plugins.multiplatform)
    id("maven-publish")
}

kotlin {
    jvm()
    js {
        nodejs()
    }
    linuxX64()

    sourceSets {
        commonMain.dependencies {
            implementation(libs.hash)
            implementation(libs.mac)
            implementation(libs.bytearray)
        }
    }
}

publishing {
    repositories {
        maven {
            url = uri("https://git.infendro.com/api/packages/Infendro/maven")
            authentication.create("header", HttpHeaderAuthentication::class)
            credentials(HttpHeaderCredentials::class) {
                val token = secret("git.token") ?: throw GradleException()

                name = "Authorization"
                value = "token $token"
            }
        }
    }
}

fun secret(
    key: String,
): String? {
    val property = key
    val environment = key
        .uppercase()
        .replace(".", "__")

    val prop = properties[property] as String?
    val env = System.getenv(environment)

    return prop ?: env
}